home *** CD-ROM | disk | FTP | other *** search
/ Softdisk Supreme / Softdisk Supreme.iso / pc / DSK Files / 0-49 / SD023b.dsk / MENU.bas < prev    next >
BASIC Source File  |  2003-06-12  |  8KB  |  159 lines
  1. 1000  REM   PROGRAM:HARVEST MENU
  2. 1010  PRINT  CHR$(4)"BLOADMENU.SCROLL"
  3. 1015  TEXT : FLASH : HTAB 8: PRINT "PRESS SPACE BAR FOR MENU";: GET K$: PRINT K$: NORMAL 
  4. 1020  DIM SC%(2):SC%(1) = 834:SC%(0) =  -912:IN = 896
  5. 1030  DIM P$(100),C$(100),T$(100),M$(200):TP = 34:BOT = 35
  6. 1040  TEXT : HOME : SPEED= 255
  7. 1050 V = 12:SC = 0
  8. 1060 RS = 0:AS = 0
  9. 1070  GOSUB 40000
  10. 1080  POKE TP,4: POKE BOT,18
  11. 1090  FOR CT = 0 TO 100: READ P$(CT): READ C$(CT): READ T$(CT): IF P$(CT) < >"END"  THEN  NEXT 
  12. 1100 P$(CT) = ""
  13. 1110 CT = CT -1
  14. 1120  GOSUB 37000
  15. 1130  GOSUB 34000
  16. 1140  ON SC +1 GOSUB 36000,35000
  17. 1150 AS = 1
  18. 10000  INVERSE :VP = V:A$ = P$(P): GOSUB 30000: NORMAL 
  19. 10010  GOSUB 38000
  20. 10020  GOSUB 30000
  21. 10030  IF KB = 32  THEN  GOSUB 41000: GOSUB 49000: GOSUB 34000:KB = 0
  22. 10040  IF KB = 13  THEN  GOSUB 45000:KB = 0
  23. 10050  IF KB = 8  THEN V$ = " ABOUT ": GOSUB 32000:KB = 0
  24. 10060  IF KB = 21  THEN V$ = " ABOUT ": GOSUB 33000:KB = 0
  25. 10070  IF KB = 27  THEN  GOSUB 19000
  26. 10080  IF KB  THEN SC =   NOT SC: ON SC +1 GOSUB 36000,35000
  27. 10090  GOTO 10000
  28. 18999  REM   <CTRL-J>CLOSING SCREEN<CTRL-J>
  29. 19000  TEXT : HOME : INVERSE : GOSUB 19120: PRINT "SOFTDISK IS PLEASED TO HAVE BROUGHT YOU": GOSUB 19120
  30. 19010  PRINT "THIS ABUNDANT SOFTWARE HARVEST.        ": GOSUB 19120: GOSUB 19120
  31. 19020  PRINT "SUBSCRIBERS WHO ARE EAGER TO SHARE     ": GOSUB 19120
  32. 19030  PRINT "APPLE TREASURES HAVE MADE IT POSSIBLE. ": GOSUB 19120: GOSUB 19120
  33. 19040  PRINT "PLEASE CONTACT CONTRIBUTORS IN REGARD  ": GOSUB 19120
  34. 19050  PRINT "TO RIGHTS OTHER THAN DISTRIBUTION IN   ": GOSUB 19120
  35. 19060  PRINT "THE SOFTDISK NETWORK.                  ": GOSUB 19120
  36. 19070  PRINT "            SOFTDISK MAGAZETTE         "
  37. 19080  PRINT "             3811 ST. VINCENT          "
  38. 19090  PRINT "        SHREVEPORT, LOUISIANA 71108    "
  39. 19100  GOSUB 19120: PRINT "$10 TO START               $55 PER YEAR"
  40. 19110  GOSUB 19120: NORMAL : VTAB 23: END 
  41. 19120  PRINT "                                       ": RETURN 
  42. 19999  REM   <CTRL-J>BUMP<CTRL-J>
  43. 20000 SK = 49200: FOR SJ = 1 TO 4: FOR SH = SJ TO 5:SG =  PEEK(SK) - PEEK(SK) + PEEK(SK): NEXT SH,SJ
  44. 20010 BC = BC +1: IF BC >2  THEN SC =   NOT SC: ON SC +1 GOSUB 36000,35000
  45. 20090  RETURN 
  46. 29998  END 
  47. 29999  REM   <CTRL-J>HOR CENTER @ VP<CTRL-J>
  48. 30000  VTAB VP: HTAB 20 - LEN(A$)/2: PRINT A$;: RETURN 
  49. 30999  REM   <CTRL-J>LINE OF -<CTRL-J>
  50. 31000  FOR A = 1 TO 40: PRINT "-";: NEXT : RETURN 
  51. 31999  REM  <CTRL-J>RUN SELECTED<CTRL-J>
  52. 32000 RS = 1: VTAB 3: HTAB 2: INVERSE : PRINT " RUN ";: HTAB 32: NORMAL : PRINT V$;: HTAB 8: PRINT "<==";: HTAB 28: PRINT "   ";:AS = 0: RETURN 
  53. 32999  REM  <CTRL-J>ABOUT SELECTED<CTRL-J>
  54. 33000 AS = 1: VTAB 3: HTAB 32: INVERSE : PRINT V$;: HTAB 2: NORMAL : PRINT " RUN ";: HTAB 28: PRINT "==>";: HTAB 8: PRINT "   ";:RS = 0: RETURN 
  55. 33999  REM  <CTRL-J>CATEGORY<CTRL-J>
  56. 34000 VP = 3:A$ = T$(P): GOSUB 30000: RETURN 
  57. 34999  REM  <CTRL-J>SCROLL DOWN SELECTED<CTRL-J>
  58. 35000  VTAB 21: HTAB 37: PRINT "/!\";: VTAB 23: HTAB 37: PRINT " ! ";: RETURN 
  59. 35999  REM  <CTRL-J>SCROLL UP SELECTED<CTRL-J>
  60. 36000  VTAB 21: HTAB 37: PRINT " ! ";: VTAB 23: HTAB 37: PRINT "\!/";: RETURN 
  61. 36999  REM  <CTRL-J>INITIALIZE SCROLL SCN<CTRL-J>
  62. 37000 B = 3: FOR A = P +1 TO P +7:VP = (B) *2:A$ = P$(A): GOSUB 30000:B = B +1: NEXT :P = 4: RETURN 
  63. 37999  REM  <CTRL-J>KET KEYPRESS<CTRL-J>
  64. 38000 KB =  PEEK(49152): IF KB >127  THEN KB = KB -128: POKE 49168,0: GOTO 38020
  65. 38010  GOTO 38000
  66. 38020  RETURN 
  67. 39999  REM  <CTRL-J>DRAW FULL SCREEN<CTRL-J>
  68. 40000  HOME :V$ = " ABOUT "
  69. 40010 A$ = "SEPTEMBER 1983 SOFTDISK HARVEST":VP = 1: GOSUB 30000
  70. 40020  GOSUB 33000
  71. 40030  HTAB 1: VTAB 4: GOSUB 31000
  72. 40040  HTAB 1: VTAB 19: GOSUB 31000
  73. 40050  PRINT "ARROWS SELECT RUN/ABOUT"
  74. 40060  PRINT "SPACE BAR SCROLLS"
  75. 40070  PRINT "ANY KEY REVERSES SCROLL DIRECTION"
  76. 40080  PRINT "<RETURN> GROKS HIGHLIGHTED ITEMS"
  77. 40090  PRINT "<ESC> TO ESCAPE";
  78. 40100  VTAB 20: HTAB 38: PRINT ".": FOR A = 21 TO 23: VTAB A: HTAB 38: PRINT "!": NEXT : VTAB 24: HTAB 38: PRINT "'";
  79. 40110  VTAB V
  80. 40120  RETURN 
  81. 40999  REM  <CTRL-J>SCROLLING<CTRL-J>
  82. 41000  ON SC +1 GOSUB 42000,43000
  83. 41090  RETURN 
  84. 41999  REM  <CTRL-J>SCROLL UP<CTRL-J>
  85. 42000  IF P > = CT  THEN  GOSUB 20000: GOTO 42090
  86. 42010  GOSUB 44100
  87. 42020  GOSUB 44000
  88. 42030 P = P +1:BC = 0
  89. 42040 VP = 18:A$ = P$(P +3): GOSUB 30000
  90. 42090  RETURN 
  91. 42999  REM  <CTRL-J>SCROLL DOWN<CTRL-J>
  92. 43000  IF P < = 4  THEN  GOSUB 20000: GOTO 43090
  93. 43010  GOSUB 44100
  94. 43020  GOSUB 44000
  95. 43030 P = P -1:BC = 0
  96. 43040 VP = 6:A$ = P$(P -3): GOSUB 30000
  97. 43090  RETURN 
  98. 43999  REM  <CTRL-J>DO SCROLL<CTRL-J>
  99. 44000  CALL SC%(SC): CALL SC%(SC)
  100. 44090  RETURN 
  101. 44099  REM  <CTRL-J>BLANK INVERSE P$<CTRL-J>
  102. 44100 VP = V:A$ = P$(P): GOSUB 30000: RETURN 
  103. 44999  REM  <CTRL-J>EXECUTIVE<CTRL-J>
  104. 45000  IF AS  THEN  GOSUB 46000
  105. 45010  IF RS  THEN  GOSUB 47000
  106. 45020  RETURN 
  107. 45999  REM  <CTRL-J>READ T.FILE<CTRL-J>
  108. 46000  HOME : PRINT 
  109. 46010  ONERR  GOTO 46060
  110. 46020  PRINT  CHR$(4)"OPEN ABOUT."P$(P)
  111. 46030  PRINT  CHR$(4)"READ ABOUT."P$(P)
  112. 46040  FOR A = 0 TO 200: CALL IN,M$(A): IF M$(A) < >"!"  THEN  NEXT 
  113. 46060 CM = A -1: POKE 216,0: IF   NOT CM  THEN CM = 199
  114. 46070  PRINT : PRINT  CHR$(4)"CLOSE"
  115. 46080  GOSUB 48000: ONERR  GOTO 46100
  116. 46090 PS = P:P = P -4: TEXT :V$ = " ABOUT ": GOSUB 40000: POKE TP,4: POKE BOT,18: GOSUB 37000:P = PS: ON SC +1 GOSUB 36000,35000: GOSUB 49000: GOSUB 34000: RETURN 
  117. 46100  RUN 1020
  118. 46999  REM  <CTRL-J>RUN IT<CTRL-J>
  119. 47000  HOME : VTAB V: PRINT C$(P): TEXT : PRINT  CHR$(4);C$(P)
  120. 47999  REM  <CTRL-J>ABOUT.TEXT<CTRL-J>
  121. 48000  VTAB 3: HTAB 1: PRINT  SPC( 27);: HTAB 12: PRINT  LEFT$(P$(P),15);:V$ = " MENU  ": GOSUB 33000
  122. 48010  VTAB 20: HTAB 19: PRINT V$;: VTAB 24: HTAB 1: PRINT "PRESS H FOR HARDCOPY";
  123. 48020  HOME : FOR ZC = 0 TO 12: PRINT M$(ZC): NEXT : PRINT M$(ZC);
  124. 48030  GOSUB 38000
  125. 48040  IF KB = 32  THEN  GOSUB 48100: GOSUB 48100:KB = 0
  126. 48042  IF KB = 8  THEN  GOSUB 32000:KB = 0
  127. 48044  IF KB = 21  THEN  GOSUB 33000:KB = 0
  128. 48050  IF KB = 13  THEN KB = 0: ON RS GOSUB 47000: GOTO 48090
  129. 48055  IF KB = 72  THEN  GOSUB 48400:KB = 0: GOTO 48020
  130. 48060  IF KB  THEN SC =   NOT SC: ON SC +1 GOSUB 36000,35000
  131. 48070  GOTO 48030
  132. 48090  RETURN 
  133. 48100  IF SC  THEN  IF ZC >12  THEN  CALL SC%(1): VTAB 5: HTAB 1:ZC = ZC -1:BC = 0: IF ZC >12  THEN  PRINT M$(ZC -13);: GOTO 48130
  134. 48110  IF   NOT SC  THEN  IF ZC <CM  THEN  CALL SC%(0): VTAB 18:ZC = ZC +1:BC = 0: HTAB 1: PRINT M$(ZC);: GOTO 48130
  135. 48120  GOSUB 20000
  136. 48130  RETURN 
  137. 48399  REM  <CTRL-J>HARDCOPY<CTRL-J>
  138. 48400  HOME : PRINT  TAB( 16);"HARDCOPY": PRINT "TURN ON THE PRINTER AND PRESS <RETURN>": GET K$: IF K$ < > CHR$(13)  THEN 48430
  139. 48405  PRINT : PRINT  CHR$(4)"PR#1"
  140. 48410  FOR CH = 0 TO CM: PRINT M$(CH): NEXT 
  141. 48420  PRINT  CHR$(4)"PR#0"
  142. 48430  RETURN 
  143. 48999  REM  <CTRL-J>CLEAR CATEGORY<CTRL-K><CTRL-J>
  144. 49000  VTAB 3: HTAB 11: PRINT  SPC( 17);: RETURN 
  145. 49999  DATA  "","","","","","","","","","","",""
  146. 50000  DATA "PACKAGE MAILING LABELS","RUN LABELS.UC","HOME & BUSINESS"
  147. 50001  DATA "EQUIPMENT INVENTORY","RUN EQUIPMENT INVENTORY","HOME & BUSINESS"
  148. 50002  DATA "RIGHT TRIANGLE","RUN RIGHT TRIANGLE","EDUCATIONAL"
  149. 50003  DATA "FACTORS","RUN FACTORS","EDUCATIONAL" 
  150. 50004  DATA "EVOLUTION","RUN EVOLUTION INTRO","EDUCATIONAL"
  151. 50005  DATA "ANIMATED ANAGRAMS","RUN ANIMATED ANAGRAMS","EDUCATIONAL"
  152. 50006  DATA "APPLOGIC","RUN APPLOGIC","GAME"
  153. 50007  DATA "F-SOLITAIRE","RUN F","GAME"
  154. 50008  DATA "TEXT-TRICKS","RUNTEXT-TRICKS","UTILITIES"  
  155. 50009  DATA "AUTO-NUMBER","BRUN AUTO-NUMBER","UTILITIES"
  156. 50010  DATA "APPLEWAIT","RUN APPLEWAIT","TUTORIAL"
  157. 50011  DATA "EDISON","RUN EDISON","ENTERTAINMENT"
  158. 50012  DATA "BLIP IS THE BLAP OF BLEEP","RUN BLIP IS THE BLAP OF BLEEP","ENTERTAINMENT"
  159. 63999  DATA END,END,END